PSO2yomiの･･･

･･･[Option]タブ [Directory]の設定は、SEGA ID の ユーザーなら変更する事無く利用出来ます。


が、ハンゲなどでは フォルダ名が違うので そのままでは使えない。


まぁ Windowsのフォルダ周りを 少しでも既知なら支障は無いハナシではありますが、
コレが意外に 端末初心者には 相当に閾が高い現実があります。

ソレを2ch的にツッ刎ねるのは簡単。　しかし おきつねさまのスタンスではナイ。


でまぁ、おきつねさまで出来るコトで対応、スクリプトで簡単に取得出来るようにしてみた。


・プレーンテキストのスクリプト　－　
fLogChk.vbs
・エンコード済みスクリプト　　　－　
fLogChk.vbe

セキュアソフトで.vbs形式がハジかれる場合は、エンコード済みのほうを試して下さい。
プレーンのほうは内容をテキストエディタで読んだり、自分で好きに変更出来ますよ


件のソースを VxEditorの .vbsファイル表示風に･･･


'***** ↓↓↓ScriptTitle↓↓↓ ********************************************************* 
    ' PSO2 LogFolderScan  
    ' - Created by LazwardFox -  

    ' Update  
    ' Release  
    ' Update  
    ' βRelease 20150606 005316 
    ' Update 20150606 003433 
    ' αRelease 20150605 235510 
    ' DevStart 20150605 232734 


'***** ↓↓↓ Memo ↓↓↓ ************************************************************** 


'***** ↓↓↓ ObjectDecralations ↓↓↓ ************************************************* 
    Option Explicit

    Dim My, MySh, Parameters, Fs
    Set My = WScript
    With My
        Set Parameters = .Arguments 'パラメーター取得 
        Set MySh = .CreateObject("WScript.Shell")
        Set Fs = .CreateObject("Scripting.FileSystemObject") 'ファイル制御 
    End With



'***** ↓↓↓ConstructDecralations↓↓↓ ********************************************************* 
    Const vbWq = """" ' 文字列データに ダブルクォーテーションを利用する為の変数。 
    Const defType = 64 ' Popupメッセージの既定表示指定  

    Const strRoot = "SEGA"
    Const strLog = "log"
    Const strTargets = "PHANTASYSTARONLINE2,PHANTASYSTARONLINE2_HanGame"


'***** ↓↓↓AuthDecralations↓↓↓ ********************************************************* 


'***** ↓↓↓ValiableConstDecralations↓↓↓ *********************************************************  
    Dim Pc, Dummy

    Dim vbWCrLf
    vbWCrLf = vbCrLf & vbCrLf

    Dim UserProf, Documents
    UserProf = MySh.ExpandEnvironmentStrings("%UserProfile%") ' ユーザーフォルダフルパス取得  
    Documents = Fs.BuildPath(UserProf, "Documents") ' MyDocumentsフォルダフルパス  

    Dim strError
    strError = "Nof Found! - " ' & vbWCrLf 


'***** ↓↓↓PublicDecralations↓↓↓ ********************************************************* 


'***** ↓↓↓Decralations↓↓↓ ********************************************************* 
    Dim arParameters, arTargets
    Dim strParent, inTarget, strTarget, blResult, strResult


' －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－ 
' －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－ 

'***** ↓↓↓MainRoutine↓↓↓ ********************************************************* 
    On Error Resume Next

    If Parameters.Count <= 0 Then 'パラメータなし 
        arParameters = Split(strTargets, ",")
    Else
        arParameters = Parameters
    End If

    strParent = Fs.BuildPath(Documents, strRoot) ' SEGAフォルダまでのフルパス 

    If Fs.FolderExists(strParent) Then ' SEGAフォルダの有無 

        For Each inTarget in arParameters
 
           strTarget = Fs.BuildPath(strParent, inTarget) ' PSO2フォルダまでのフルパス 

            If Fs.FolderExists(strTarget) Then ' PSO2フォルダの有無 

                strTarget = Fs.BuildPath(strTarget, strLog) ' logフォルダまでをフルパスで 

                If Fs.FolderExists(strTarget) Then ' logフォルダの有無 
                    blResult = True
                    strResult = "Existed♪" & vbWCrLf & strTarget
                Else
                    blResult = False
                    strResult = strError & "[Log]Folder"
                End If

                Exit For

            End If

            blResult = False
            strResult = strError & "[PSO2]Folder"

        Next

    Else
            blResult = False
            strResult = strError & "[SEGA]Folder"

    End If

    MySh.Popup "-- Result --" & vbWCrLf & strResult, 60, "PSO2 UserFolder ExistedChecker", defType

    If blResult Then
        strTarget = Replace(strTarget, Documents, "")
        strTarget = Replace(strTarget, "\" & strLog, "")
        InputBox "-- for Settings --" & vbWCrLf & "以下文字列を、PSO2yomiの設定画面" _
                    & vbCrLf & "[Option]タブ の [Directory]枠に" & vbCrLf & _
                    "コピペして下さい。", "PSO2 UserFolder ExistedChecker", strTarget
    End If


    '▼ － 終了－ ▼  
    Set Parameters = Nothing
    Set Fs = Nothing
    Set MySh = Nothing
    My.Quit


' －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－ 
' －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－ 

'***** ↓↓↓ CreatingFunctions ↓↓↓ ********************************************************* 


'***** ↓↓↓ LimitedFunctions ↓↓↓ ********************************************************* 


'***** ↓↓↓ GlobalFunctions ↓↓↓ *********************************************************